EmguCV学习条记 VB.Net 10.1 人脸检测 CascadeClassifier类

版权声明：本文为博主原创文章，转载请在明显位置标明本文出处以及作者网名，未经作者允许不得用于商业目的。

EmguCV是一个基于OpenCV的开源免费的跨平台盘算机视觉库,它向C#和VB.NET开辟者提供了OpenCV库的大部分功能。
教程VB.net版本请访问：EmguCV学习条记 VB.Net 目次-CSDN博客
教程C#版本请访问：EmguCV学习条记 C# 目次-CSDN博客
笔者的博客网址：https://blog.csdn.net/uruseibest
教程配套文件及相干分析以及怎样得到pdf教程和代码，请移步：EmguCV学习条记
学习VB.Net知识，请移步： vb.net 教程 目次_vb中怎样用datagridview-CSDN博客
 学习C#知识，请移步：C# 教程 目次_c#教程目次-CSDN博客
 
10.1 人脸检测 CascadeClassifier类

CascadeClassifier类是EmguCV中用于人脸检测的一个告急类。它是基于Haar特性的级联分类器（Cascade Classifier，是一种基于Haar特性的目的检测算法），它具有较高的检测精确率，常用于人脸检测、行人检测等场景。
CascadeClassifier类的根本原理可以分为以下几个步调：
1. 特性提取。起首，必要对图像举行特性提取，将图像转换为一组特性向量。Haar特性是一种基于图像亮度厘革的特性，可以用于检测人脸的边沿、线段和地区等特性。
2. 练习分类器。根据特性向量，可以练习一个级联分类器，将人脸和非人脸地区举行分类。级联分类器由多个弱分类器构成，每个弱分类器可以检测特定的Haar特性。
3. 应用分类器。将分类器应用于图像中的每个窗口，检测此中是否包罗人脸。由于Haar特性的盘算量较大，可以接纳图像金字塔的方法对图像举行缩放，以便在差别标准的图像中举行人脸检测。
在实现中，CascadeClassifier类提供了一系列的接口函数，可以用于加载练习好的分类器、设置检测参数、举行人脸检测等利用。在使用时，必要调用CascadeClassifier类中的DetectMultiScale函数，传入待检测的图像和检测参数，可以得到检测效果，即图像中全部人脸的位置和巨细。必要注意的是，级联分类器固然在人脸检测等场景中体现精良，但在一些复杂场景下大概会出现漏检或误检的环境。
CascadeClassifier常用方法：
1. CascadeClassifier构造函数
该方法用于创建CascadeClassifier对象，并加载指定的级联分类器文件。其语法为：
Public Sub New(ByVal fileName As String)
参数分析：

• fileName：要加载的级联分类器XML文件。常用的级联分类器XML文件有：
  

• haarcascade_frontalface_alt.xml：人脸检测器，使用的是Haar特性，可以大概检测正脸、侧脸、带眼镜等多种环境的人脸。
  
• haarcascade_eye.xml：眼睛检测器，可以大概检测人脸中的眼睛。
  
• haarcascade_fullbody.xml：行人检测器，可以大概检测整个行人的图像。
  
• haarcascade_upperbody.xml：上半身检测器，可以大概检测行人的上半身地区。
  
• haarcascade_car.xml：车辆检测器，可以大概检测汽车的前部和侧部。
  

2. DetectMultiScale方法
该方法用于对图像举行目的检测并返回检测效果。其声明如下：
Public Function DetectMultiScale (
         image As IInputArray,
         Optional scaleFactor As Double = 1.1,
         Optional minNeighbors As Integer = 3,
         Optional minSize As Size = Nothing,
         Optional maxSize As Size = Nothing
) As Rectangle()
参数分析：

• Image：待检测的图像。
  
• scaleFactor：缩放比例因子，缩放比例越小，检测时间越长，检测精度越高。
  
• minNeighbors：符合检测标记的个数，用于控制对象检测时间的误检率和漏检率，参数越大，检测效果越准确，但是漏检率也会增长。
  
• minSize：检测目的的最小尺寸，小于此尺寸的目的将被忽略。
  
• maxSize：检测目的的最大尺寸，大于此尺寸的目的将被忽略。
  

返回值：
返回一个矩形数组，体现图像中全部检测到的目的位置和巨细。

下面将提供多个代码来分析级联分类器的使用。
【代码位置：frmChapter10】Button1_Click

    '级联分类器检测人脸

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

        '使用练习好的某个辨认文件

        Dim face As New CascadeClassifier("C:\learnEmgucv\haarcascade\haarcascade_frontalface_alt2.xml")

        Dim m As New Mat("C:\learnEmgucv\hy.jpg", ImreadModes.Color)

        Dim rects() As Rectangle

        '使用级联分类器举行检测

        rects = face.DetectMultiScale(m)

        '输出矩形框

        For i As Integer = 0 To rects.Length - 1

            CvInvoke.Rectangle(m, rects(i), New MCvScalar(0, 0, 255), 2)

        Next

        ImageBox1.Image = m

End Sub
输出效果如下图所示：

图10-1 多个人脸检测

两个级联分类器团结使用来检测鼻子：
【代码位置：frmChapter10】Button2_Click

   '两个级联分类器团结使用来检测鼻子

    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click

        '级联分类器，练习好的人脸文件

        Dim face As New CascadeClassifier("C:\learnEmgucv\haarcascade\haarcascade_frontalface_alt2.xml")

        '级联分类器，练习好的鼻子文件

        Dim nose As New CascadeClassifier("C:\learnEmgucv\haarcascade\haarcascade_mcs_nose.xml")

        Dim m As New Mat("C:\learnEmgucv\hy1.jpg", ImreadModes.Color)

        Dim rectfaces() As Rectangle

        rectfaces = face.DetectMultiScale(m)

        For i As Integer = 0 To rectfaces.Length - 1

            CvInvoke.Rectangle(m, rectfaces(i), New MCvScalar(0, 0, 255), 2)

            '得到已经取得的人脸地区图像，将在此地区内举行检测

            Dim mFace As New Mat(m, rectfaces(i))

            Dim rectnoses() As Rectangle

            rectnoses = nose.DetectMultiScale(mFace)

            '绘制出检测到的鼻子地区矩形框

            For j As Integer = 0 To rectnoses.Length - 1

                CvInvoke.Rectangle(mFace, rectnoses(j), New MCvScalar(0, 255, 0), 2)

            Next

        Next

        ImageBox1.Image = m

End Sub
输出效果如下图所示：

 

图10-2 检测鼻子

检测并标识视频中的人脸：
【代码位置：frmChapter10】Button3_Click、vcCascade_ImageGrabbed、Button4_Click

    Dim vcCascade As VideoCapture

    Dim vcface As CascadeClassifier

    '是否制止视频标记

    Dim stopVC As Boolean

    '检测并标识视频中的人脸

    '详细检测代码在vcCascade_ImageGrabbed中

    Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click

        vcCascade = New VideoCapture(0)

        If vcCascade.IsOpened = False Then

            MessageBox.Show("打开文件失败")

            Exit Sub

        End If

        stopVC = False

        '添加ImageGrabbed变乱

        AddHandler vcCascade.ImageGrabbed, AddressOf vcCascade_ImageGrabbed

        vcCascade.Start()

        vcface = New CascadeClassifier("C:\learnEmgucv\haarcascade\haarcascade_frontalface_alt2.xml")

    End Sub

    '检测人脸

    Private Sub vcCascade_ImageGrabbed(sender As Object, e As EventArgs)

        If stopVC = True Then

            '制止

            vcCascade.Stop()

            '开释资源

            vcCascade.Dispose()

            '取消变乱

            RemoveHandler vcCascade.ImageGrabbed, AddressOf vcCascade_ImageGrabbed

            Exit Sub

        End If

        Dim nextframe As New Mat

        vcCascade.Retrieve(nextframe)

        Dim rectfaces() As Rectangle

        '检测人脸

        rectfaces = vcface.DetectMultiScale(nextframe)

        For i As Integer = 0 To rectfaces.Length - 1

            '绘制人脸矩形框

            CvInvoke.Rectangle(nextframe, rectfaces(i), New MCvScalar(0, 0, 255), 2)

        Next

        ImageBox1.Image = nextframe

        Threading.Thread.Sleep(40)

    End Sub

    '制止视频

    Private Sub Button4_Click(sender As Object, e As EventArgs) Handles Button4.Click

        stopVC = True

End Sub
输出效果由于笔者比力丑而表现空缺。